Форум компании ИНФИН

@ECHO OFF
CLS
CD /D "%~dp0"
:: --- АВТОМАТИЧЕСКОЕ СТРАХОВОЕ КОПИРОВАНИЕ ПОД Sybase ASA 6/7/8/9/10 ---
:: Пример запуска: asa_backup.cmd infin_sample C:\BACKUP 12 DAY
::
:: В примере передаются из коммандной строки три параметра:
:: - первый ОБЯЗАТЕЛЕН - это имя алиаса источника данных ODBC.
:: - второй необязательный - путь создания страховой копии.
:: Если он не указан используется текущая директория...
:: Директория с установленным Sybase считывается автоматически из реестра.
:: И соответственно все это работает только на том компьютере где база
:: описана в ODBC и установлен Sybase!
:: Можно можно вписать жесткие значения параметров в трех последующих
:: строках:
:: вместо %1 - имя алиаса
:: вместо %2 - путь создания бэкапа.

SETLOCAL
SET "SOURCE_NAME=%~1"
SET "BACKUP_DIR=%~2"
::Тип бэкапа: DAY, WEEK, MONTH, YEAR
::День недели число
::1 - Воскресенье
::2 - Понедельник
::3 - Вторник
::4 - Среда
::5 - Четверг
::6 - Пятница
::7 - Суббота
:: День недели бэкап которого считается недельным
SET "WEEK_DAY_BACKUP=1"
:: Бэкап последнего числа месяца считается месячным
:: Бэкап последнего числа года считается годовым
:: Количество хранимых страховых копий по типам
SET "REZERV_DAY=6"
SET "REZERV_WEEK=5"
SET "REZERV_MONTH=11"
SET "REZERV_YEAR=50"
:: ПРИМЕЧАНИЕ: имя архива будет иметь маску:
:: %SOURCE_NAME%_ГГГГ_ММ_ДД~ЧЧ-ММ_%TYPE_BACKUP%.7z

CALL :PROVERKA
CALL :ASA_PATHS
CALL :ASAMAN
CALL :BACKUP_PATHS
CALL :SYS_TYPE
CALL :DATE_SET
CALL :DATE_ECHO
CALL :BACKUP
CALL :ARC
CALL :REZERV_TRIM

ENDLOCAL
GOTO :EOF

:PROVERKA
:: Проверка указан ли параметр "Источник данных"
IF NOT X%SOURCE_NAME%X == XX GOTO :SOURCE
ECHO Да вы даже не указали что бэкапить - я так не играю!
ECHO Быстро введите имя источника данных в ODBC:
SET /P SOURCE_NAME=
GOTO :PROVERKA
:SOURCE
GOTO :EOF

:ASA_PATHS
:: Определение пути установки Sybase и проверка существования нужных утилит
ECHO Ищем директорию Sybase Adaptive Server Anyware...
CALL :REG_READ "HKCU\SOFTWARE\ODBC\ODBC.INI\%SOURCE_NAME%" "Driver" "SYBASE_DIR"
CALL :REG_READ "HKLM\SOFTWARE\ODBC\ODBC.INI\%SOURCE_NAME%" "Driver" "SYBASE_DIR"
CALL :REG_READ "HKLM\SOFTWARE\WOW6432NODE\ODBC\ODBC.INI\%SOURCE_NAME%" "Driver" "SYBASE_DIR"
IF "%SYBASE_DIR%"=="" ECHO Не найдено описание источника данных в ODBC & GOTO :ERROR
FOR /F "USEBACKQ TOKENS=1 DELIMS=" %%i IN ('%SYBASE_DIR%') DO SET "SYBASE_DIR=%%~dpi"
:: Отбрасывание последнего символа "\" в пути Sybase
SET "LAST_CHAR=%SYBASE_DIR:~-1%"
IF "%LAST_CHAR%"=="\" SET "SYBASE_DIR=%SYBASE_DIR:~0,-1%"
:: Проверка существования утилиты для создания бэкапа
IF NOT EXIST "%SYBASE_DIR%\dbbackup.exe" (ECHO Не найдена утилита для создания бэкапа dbbackup.exe & GOTO :ERROR )
(ECHO Sybase ASA найден в %SYBASE_DIR% )
GOTO :EOF

:ASAMAN
:: Проверка существования источника данных и определение версии Sybase
ECHO Проверка существования источника данных
"%SYBASE_DIR%\dbping.exe" -d -c "DSN=%SOURCE_NAME%;UID=DBA;PWD=SQL;astart=1" 1>NUL
IF ERRORLEVEL 1 (ECHO Указанный источник данных %SOURCE_NAME% не существует в ODBC либо недоступен! & GOTO :ERROR)
ECHO Источник данных %SOURCE_NAME% существует в ODBC и доступен
:: Определение версии Sybase
CALL :REG_READ "HKCU\SOFTWARE\ODBC\ODBC.INI\ODBC Data Sources" "%SOURCE_NAME%" "SYBASE_VERSION"
ECHO Используюмое СУБД - %SYBASE_VERSION%
CALL :REG_READ "HKLM\SOFTWARE\ODBC\ODBC.INI\ODBC Data Sources" "%SOURCE_NAME%" "SYBASE_VERSION"
ECHO Используюмое СУБД - %SYBASE_VERSION%
CALL :REG_READ "HKLM\SOFTWARE\WOW6432NODE\ODBC\ODBC.INI\ODBC Data Sources" "%SOURCE_NAME%" "SYBASE_VERSION"
ECHO Используюмое СУБД - %SYBASE_VERSION%
GOTO :EOF

:BACKUP_PATHS
:: Проверка пути бэкапа
IF "%BACKUP_DIR%" == "" ( ECHO Не указан путь к бэкапу - создаем в текущей директории & SET "BACKUP_DIR=%~dp0")
IF "%REZERV_NUM%" == "" SET "REZERV_NUM=1000"
:: Отбрасывание последнего символа "\" в пути бэкапа
SET "LAST_CHAR=%BACKUP_DIR:~-1%"
IF "%LAST_CHAR%"=="\" SET "BACKUP_DIR=%BACKUP_DIR:~0,-1%"
:: Создание целевой папки для страхового копирования с проверкой существования
IF NOT EXIST "%BACKUP_DIR%" MD "%BACKUP_DIR%"
IF NOT EXIST "%BACKUP_DIR%" (ECHO Указанная папка для создания копии недоступна! & GOTO :ERROR)
ECHO Страховое копирование будет выполнено в папку %BACKUP_DIR%
GOTO :EOF

:SYS_TYPE
:: Определение разрядности системы для использования нужной версии архиватора
ECHO "%PROCESSOR_ARCHITECTURE%""%PROCESSOR_ARCHITEW6432%"|1>NUL 2>NUL FIND /I "AMD64"&&SET "ARC_DIR=%~dp0X64"||SET "ARC_DIR=%~dp0X32"
:: Отбрасывание последнего символа "\" в пути архиватора
SET "LAST_CHAR=%ARC_DIR:~-1%"
IF "%LAST_CHAR%"=="\" SET "ARC_DIR=%ARC_DIR:~0,-1%"
GOTO :EOF

:DATE_SET
:: Определение параметров текущей даты и типа бэкапа
ECHO wscript.ECHO YEAR(DATE)^&"_"^&RIGHT(0^&MONTH(DATE),2)^&"_"^&RIGHT(0^&DAY(DATE),2)^&"_"^& DAY(DATESERIAL(YEAR(DATE),MONTH(DATE)+1,1-1))^&"_"^&WEEKDAY(DATE)^&"_"^&RIGHT(0^&hour(TIME),2)^&"_"^&RIGHT(0^&minute(TIME),2) 1>"%TEMP%\tmp.vbs"
FOR /F "TOKENS=1,2,3,4,5,6,7 DELIMS=_" %%a IN ('cscript "%TEMP%\tmp.vbs" //Nologo') DO SET "TEK_YEAR=%%a"&SET "TEK_MONTH=%%b"&SET "TEK_DAY=%%c"&SET "LAST_DAY=%%d"&SET "TEK_WEEK=%%e"&SET "TEK_HOUR=%%f"&SET "TEK_MINUTE=%%g"
IF EXIST "%TEMP%\tmp.vbs" DEL "%TEMP%\tmp.vbs"
SET "TYPE_BACKUP=DAY"
IF "%WEEK_DAY_BACKUP%"=="%TEK_WEEK%" SET "TYPE_BACKUP=WEEK"
IF "%TEK_DAY%"=="%LAST_DAY%" SET "TYPE_BACKUP=MONTH"
IF "%TEK_MONTH%"=="12" (IF "%TEK_DAY%"=="%LAST_DAY%" (SET "TYPE_BACKUP=YEAR"))
CALL SET "REZERV_NUM=%%REZERV_%TYPE_BACKUP%%%"
SET "ARC_NAME=%SOURCE_NAME%_%TEK_YEAR%_%TEK_MONTH%_%TEK_DAY%~%TEK_HOUR%-%TEK_MINUTE%_%TYPE_BACKUP%"
GOTO :EOF

:DATE_ECHO
:: Вывод значений текущих переменных времени даты и типа бэкапа
ECHO Текущий год: "%TEK_YEAR%"
ECHO Текущий месяц: "%TEK_MONTH%"
ECHO Текущий день: "%TEK_DAY%"
ECHO Последнее число месяца: "%LAST_DAY%"
ECHO Текущий день недели: "%TEK_WEEK%"
ECHO Текущий час: "%TEK_HOUR%"
ECHO Текущая минута: "%TEK_MINUTE%"
ECHO Текущий тип бэкапа: "%TYPE_BACKUP%"
ECHO Количество хранимых копий для текущего типа: "%REZERV_NUM%"
ECHO Текущее имя архива: "%ARC_NAME%"
GOTO :EOF

:BACKUP
:: Запуск утилиты страхового копирования из директории Sybase
"%SYBASE_DIR%\dbbackup.exe" -x -d -t -c "DSN=%SOURCE_NAME%;UID=DBA;PWD=SQL" "%BACKUP_DIR%" /y
IF ERRORLEVEL 1 ( ECHO Не удается создать бэкап в папку %BACKUP_DIR% & GOTO :ERROR )
IF ERRORLEVEL 9 ( ECHO Что-то не в порядке с именем алиаса & GOTO :ERROR )
ECHO Страховое копирование выполнено скриптом asa_backup.cmd (by Yurkesha). >"%BACKUP_DIR%\version.txt"
ECHO Дата создания копии %DATE%. Время создания %TIME%. >>"%BACKUP_DIR%\version.txt"
ECHO Используемое СУБД - %SYBASE_VERSION% >>"%BACKUP_DIR%\version.txt"
ECHO Выполнено с компьютера - %COMPUTERNAME% >>"%BACKUP_DIR%\version.txt"
GOTO :EOF

:ARC
IF EXIST "%ARC_DIR%\7z.exe" (
"%ARC_DIR%\7z.exe" a -t7z "%BACKUP_DIR%\%ARC_NAME%.7z" "%BACKUP_DIR%\*.db" "%BACKUP_DIR%\*.log" "%BACKUP_DIR%\version.txt" -ms -mmt -mx7&&(DEL /Q /F "%BACKUP_DIR%\*.db" &DEL /Q /F "%BACKUP_DIR%\*.log" &del /q /f "%BACKUP_DIR%\version.txt")
ECHO Страховая копия успешно создана и заархивирована...
)
GOTO :EOF

:REZERV_TRIM
ECHO Удаление устаревших резервных копий
FOR /F "SKIP=%REZERV_NUM% USEBACKQ TOKENS=1 DELIMS=" %%a IN (`DIR /O:-N /B "%BACKUP_DIR%\%SOURCE_NAME%_20??_??_??~??-??_%TYPE_BACKUP%.7z"`) DO DEL /Q /F "%BACKUP_DIR%\%%a"
GOTO :EOF

:REG_READ
:: 1-й параметр = раздел реестра для чтения
:: 2-й параметр = имя считываемого параметра
:: 3-й параметр = имя переменной окружения куда считываем результат
:: Пример:
:: CALL :REG_READ "HKCU\SOFTWARE\ODBC\ODBC.INI\%SOURCE_NAME%" "Driver" "SYBASE_DIR"
FOR /F "USEBACKQ TOKENS=1,2* EOL=;" %%a IN (`REG QUERY "%~1" /v "%~2" 2^>NUL ^|FIND /I "%~2" 2^>NUL`) DO IF /I "%%a"=="%~2" SET "%~3=%%c"
GOTO :EOF

:ERROR
ECHO Произошло досадное недоразумение - резервная копия не создана ...
EXIT
GOTO :EOF